# This file is part of the TrinityCore Project. See AUTHORS file for Copyright information
#
# This file is free software; as a special exception the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

GroupSources(${CMAKE_CURRENT_SOURCE_DIR})

CollectIncludeDirectories(
  ${CMAKE_CURRENT_SOURCE_DIR}
  PUBLIC_INCLUDES
  EXCLUDE
  ${CMAKE_CURRENT_SOURCE_DIR}/PrecompiledHeaders)

# Provide an interface target for the game project to allow
# dependent projects to build meanwhile.
add_library(game-interface INTERFACE)

target_include_directories(game-interface
  INTERFACE
    ${PUBLIC_INCLUDES})

target_link_libraries(game-interface
  INTERFACE
    shared
    mmaps_common)

# Add BUILD_PLAYERBOT compile definition to game-interface
# This is CRITICAL for playerbot module to see WorldSession as polymorphic
if(BUILD_PLAYERBOT)
  target_compile_definitions(game-interface
    INTERFACE
      BUILD_PLAYERBOT=1)
      
  target_include_directories(game-interface
    INTERFACE
      ${CMAKE_SOURCE_DIR}/src/modules/Playerbot
      ${CMAKE_SOURCE_DIR}/src/modules/Playerbot/Network
      ${CMAKE_SOURCE_DIR}/src/modules/Playerbot/Core)
endif()

add_library(game)

CollectAndAddSourceFiles(
  game
  ${CMAKE_CURRENT_SOURCE_DIR}
  EXCLUDE
  ${CMAKE_CURRENT_SOURCE_DIR}/PrecompiledHeaders)

target_include_directories(game
  PRIVATE
    ${CMAKE_CURRENT_BINARY_DIR})

# Add modules-common include path for Update/ModuleUpdateManager.h
# This is required for World.cpp to access the shared module update system
if(TARGET modules-common)
  target_link_libraries(game
    PRIVATE
      modules-common)
endif()

# Add BUILD_PLAYERBOT compile definition and include paths when playerbot module is enabled
# This is CRITICAL for WorldSession.cpp to include the is_bot parameter in constructor
# and for World.cpp to include Playerbot headers (which need TBB)
if(BUILD_PLAYERBOT)
  target_compile_definitions(game
    PRIVATE
      BUILD_PLAYERBOT=1)
  target_include_directories(game
    PRIVATE
      ${CMAKE_SOURCE_DIR}/src/modules/Playerbot)
  # Link to playerbot-dependencies to get TBB include paths for BotSpawner.h
  if(TARGET playerbot-dependencies)
    target_link_libraries(game PRIVATE playerbot-dependencies)
  endif()
endif()

target_link_libraries(game
  PRIVATE
    trinity-core-interface
  PUBLIC
    game-interface)

if(TARGET efsw)
  target_link_libraries(game
    PRIVATE
      efsw)
endif()

set_target_properties(game
  PROPERTIES
    COMPILE_WARNING_AS_ERROR ${WITH_WARNINGS_AS_ERRORS}
    DEFINE_SYMBOL TRINITY_API_EXPORT_GAME
    FOLDER "server")

if(BUILD_SHARED_LIBS)
  if(UNIX)
    install(TARGETS game
      LIBRARY
        DESTINATION lib)
  elseif(WIN32)
    install(TARGETS game
      RUNTIME
        DESTINATION "${CMAKE_INSTALL_PREFIX}")
  endif()
endif()

# Generate precompiled header
if(USE_COREPCH)
  add_cxx_pch(game PrecompiledHeaders/gamePCH.h)
endif()
